How to hide updates in Win7 and Win8

bphlpt · Sep 13, 2013

Reposted from http://www.msfn.org/board/topic/163162-hide-bing-desktop-and-other-windows-updates/
maxXPsoft said:
You can use this even on a installed installation.
EDIT: I have not tried this on Windows 8 yet. ricktendo Edit: tested on Windows 8 and it worked like a charm :thumbup
I do not recommend this on XP. I added just a few and it got about 8.
Make sure you are fully updated minus things you don't want or it takes awhile to cycle through 108 updates waiting ..... :w00t:

After I complete my Unattended setup I get Windows updates for things I don't want. Rather than disable WU I'd rather have fun figuring out how to disable what I don't want.
There are other scripts out there but none as flexible as this. You have to make sure you are connected to internet before running.

I use cmd /c start /wait wscript HideKBs_BingDesktop.vbs on my unattended because I am applying updates after this.
On Windows 7 you can just double click to run it as long as you have permissions

Save as HideKBs_BingDesktop.vbs
Code:
' Maxpsoft May 30, 2013, 9:34:15 PM
' 06/18/2013 Add extra for Bing Desktop v1.3
' 06/28/2013 Updated to continue searching as long as it is finding something otherwise Quit
'
' Original Mike.Moore Dec 17, 2012 on answers.microsoft but when ran it Hide everything so no good.
' Link to script: http://www.msfn.org/board/topic/163162-hide-bing-desktop-and-other-windows-updates/
' You may freely use this script as long as you copy it complete and it remains the same except for adjusting hideupdates.
' If I need to change something then let me know so all may benefit.
 
Dim WSHShell, StartTime, ElapsedTime, strUpdateName, strAllHidden
Dim Checkagain 'Find more keep going otherwise Quit
 
Dim hideupdates(3)    'TO ADD 1 EDIT THE (3) AND ADD another hideupdates(#)
 
hideupdates(0) = "KB2592687" 'Remote Desktop Protocol 8.0
hideupdates(1) = "KB2709981" 'Windows Media Player 12
hideupdates(2) = "Bing Desktop" 'With this we get all versions
hideupdates(3) = "Silverlight"
 
Set WSHShell = CreateObject("WScript.Shell")
 
StartTime = Timer 'Start the Timer
 
Set updateSession = CreateObject("Microsoft.Update.Session")
updateSession.ClientApplicationID = "MSDN Sample Script"
Set updateSearcher = updateSession.CreateUpdateSearcher()
Set searchResult = updateSearcher.Search("IsInstalled=0 and Type='Software' and IsHidden=0")
 
Checkagain = "True"
 
For K = 0 To 10 'Bing Desktop has 4, Silverlight has 5
  If Checkagain = "True" Then
    Checkagain = "False"
    CheckUpdates
    ParseUpdates
  End if
Next
 
ElapsedTime = Timer - StartTime
strTitle = "Bing Desktop and Windows Updates Hidden."
strText = strAllHidden
strText = strText & vbCrLf & ""
strText = strText & vbCrLf & "Total Time " & ElapsedTime
intType = vbOkOnly
 
'Silent just comment these 2 lines with a ' and it will run and quit
Set objWshShell = WScript.CreateObject("WScript.Shell")
intResult = objWshShell.Popup(strText, ,strTitle, intType)
 
'Open Windows Update after remove the comment '
'WshShell.Run "%windir%\system32\control.exe /name Microsoft.WindowsUpdate"
 
WScript.Quit
 
Function ParseUpdates 'cycle through updates
  For I = 0 To searchResult.Updates.Count-1
    Set update = searchResult.Updates.Item(I)
    strUpdateName = update.Title
    'WScript.Echo I + 1 & "> " & update.Title
    For j = 0 To UBound(hideupdates)
    if instr(1, strUpdateName, hideupdates(j), vbTextCompare) = 0 then
    Else
          strAllHidden = strAllHidden _
          & vbcrlf & update.Title
      update.IsHidden = True'
      Checkagain = "True"
    end if
    Next
  Next
End Function
 
Function CheckUpdates 'check for new updates cause Bing Desktop has 3
  Set updateSession = CreateObject("Microsoft.Update.Session")
  updateSession.ClientApplicationID = "MSDN Sample Script"
  Set updateSearcher = updateSession.CreateUpdateSearcher()
  Set searchResult = _
  updateSearcher.Search("IsInstalled=0 and Type='Software' and IsHidden=0")
End Function
Click to expand...
maxXPsoft said:
'Tomorrow' said:

Can you please add Malicious Software Removal Tool and KB971033 ?
There might be others but off hand i remember these two buggers.
Click to expand...

To add or remove one all you have to do is edit this part
Dim hideupdates(4) 'TO ADD 1 EDIT THE (3) AND ADD another hideupdates(#)

hideupdates(0) = "KB2592687" 'Remote Desktop Protocol 8.0
hideupdates(1) = "KB2709981" 'Windows Media Player 12
hideupdates(2) = "Bing Desktop" 'With this we get all versions
hideupdates(3) = ".NET Framework 4.5"
hideupdates(4) = "KB971033"

Or if you want then remove Windows Media Player 12 or the .NET Framework 4.5 and replace with something else
Code:
hideupdates(3) = ".NET Framework 4.5"
replace with
hideupdates(3) = "KB971033"
Or if you use .NET Framework 4.5 then do this
Dim hideupdates(2) 'TO ADD 1 EDIT THE (3) AND ADD another hideupdates(#)

hideupdates(0) = "KB2592687" 'Remote Desktop Protocol 8.0
hideupdates(1) = "KB2709981" 'Windows Media Player 12
hideupdates(2) = "Bing Desktop" 'With this we get all versions
'hideupdates(3) = ".NET Framework 4.5"

I built it to be easy to adjust but if you need help just post what you want to remove
Click to expand...
Cheers and Regards

Log in or Sign up

How to hide updates in Win7 and Win8

bphlpt A lowly staff member Staff Member

Share This Page

Log in or Sign up

How to hide updates in Win7 and Win8

bphlpt A lowly staff member Staff Member

Share This Page

Useful Searches